This weekend, it's all about 3000 timing
March 8, 2012
Editor's Note: Daylight Saving Time begins at 2AM local time around most of the world this weekend. A lot of HP 3000s run around the clock to serve companies, so a plan to keep the 3000 on time is essential. The founder of the MPE-OpenSource.org, HP 3000 open source repository, Brian Edminster, offers a plan, experience and a sample jobstream to help get you through our semi-annual time change.
By Brian Edminster
Here's an important implementation note for anyone that wants to put up a 'time synchronization' client on their HP 3000: Do not use it to adjust for spring and fall time-changes! Use a job that runs on the appropriate dates/times to do a 'setclock timezone=' command. I have an example below that is a derivative work from something originally posted by Sam Knight of Jacksonville University, way back in April, 2004 on the 3000-L mailing list.
I've updated the job to be more readable, to account for a 'looping' effect that I found in the fall from running on a fast CPU, and to run at 2AM -- the 'official' time that time-changes apply. I have this job set to be intiated by 'SYSSTART.PUB.SYS' on server bootup, and then automatically reschedule itself each Sunday at 2AM.
Here's the spring and fall time change jobstream code. All are welcome to use, and modify for specific needs. Note that it's set up for the Eastern US time zone. (That's the TIMEZONE = W5:00 -- meaning the number of hours different than GMT -- and TIMEZONE = W4:00 lines.) Modify these lines as necessary for your timezone.
!JOB TIMECHG,MANAGER/user-passwd.SYS/acct-passwd;hipri;PRI=CS;OUTCLASS=,1
!
!setvar Sunday, 1
!
!setvar March, 3
!setvar November, 11
!
!showclock
!if hpday = Sunday and &
! hpmonth = November and &
! hpdate < 8 then
! comment (first Sunday of November)
! SETCLOCK TIMEZONE = W5:00
! TELLOP ********************************************
! TELLOP Changing the system clock to STANDARD TIME.
! TELLOP The clock will S L O W D O W N until
! TELLOP we have fallen back one hour.
! TELLOP ********************************************
!elseif hpday = Sunday and &
! hpmonth = March and &
! hpdate > 7 and hpdate < 15 then
! comment (second Sunday of March)
! SETCLOCK TIMEZONE = W4:00
! TELLOP *********************************************
! TELLOP Changing the system clock to DAYLIGHT SAVINGS
! TELLOP TIME. The clock jumped ahead one hour.
! TELLOP *********************************************
!else
! comment (no changes today!)
! TELLOP *********************************************
! TELLOP No Standard/Daylight Savings Time Chgs Req'd
! TELLOP *********************************************
!endif
!
!comment - to avoid 'looping' on fast CPU's pause long enough for
!comment - local clock time to be > 2:00a, even in fall...
!while hphour = 2 and hpminute = 0
! TELLOP Pausing 1 minute... waiting to pass 2am
! TELLOP Current Date/Time: !HPDATEF - !HPTIMEF
! showtime
! pause 60
!endwhile
!
!stream timechg.jcl.sys;day=sunday;at=02:00
!showclock
!EOJ